适用对象:yesSQL ServeryesAzure SQL 数据库noAzure SQL 数据仓库no并行数据仓库 编写用户定义类型 (UDT) 的定义时,必须根据是要将 UDT 作为类还是作为结构实现以及您所选择的格式和序列化选项来实现各种功能。
在本部分中的示例说明了实现点UDT 作为结构(或结构在 Visual Basic 中)。 点UDT 由 X 和 Y 坐标作为属性过程。
定义 UDT 时需要下列命名空间:
Imports System
Imports System.Data.SqlTypes
Imports Microsoft.SqlServer.Server
using System;
using System.Data.SqlTypes;
using Microsoft.SqlServer.Server;
Microsoft.SqlServer.Server命名空间包含您的 UDT 的各种属性所需的对象和System.Data.SqlTypes命名空间包含表示类SQL Server可用于该程序集的本机数据类型。 当然,还可能存在程序集正常运行所需的其他命名空间。 点UDT 还使用System.Text用于处理字符串的命名空间。
Note:
Visual c + + 数据库对象,例如使用编译的 Udt /clr: pure不再支持执行。
指定属性
属性确定如何使用序列化来构造 UDT 的存储表示形式以及如何按值将 UDT 传输到客户端。
Microsoft.SqlServer.Server.SqlUserDefinedTypeAttribute是必需的。 Serializable属性是可选的。 此外可以指定Microsoft.SqlServer.Server.SqlFacetAttribute提供有关 UDT 的返回类型的信息。 有关详细信息,请参阅 CLR 例程的自定义属性。
Point UDT 属性
Microsoft.SqlServer.Server.SqlUserDefinedTypeAttribute设置的存储格式点UDT 到本机。 IsByteOrdered设置为true,这样可以保证的比较结果进行相同 SQL Server 中相同的比较好像在托管代码中执行的位置。 UDT 实现System.Data.SqlTypes.INullable接口以使 UDT 为 null 的注意。
下面的代码段显示了有关的特性点UDT。
<Serializable(), SqlUserDefinedTypeAttribute(Format.Native, _
IsByteOrdered:=True)> _
Public Structure Point
Implements INullable
[Serializable]
[Microsoft.SqlServer.Server.SqlUserDefinedType(Format.Native,
IsByteOrdered=true)]
public struct Point : INullable
{
实现为 Null 性
除了为您的程序集正确指定属性外,UDT 还必须支持为 Null 性。 加载到 UdtSQL Server是可识别 null 的但为了使 UDT 能够识别 null 值,UDT 必须实现System.Data.SqlTypes.INullable接口。
必须创建一个名为属性IsNull,需要确定值是否为 null 从 CLR 代码中。 当 SQL Server 发现 UDT 的 Null 实例时,会使用正常的 Null 处理方法来保留 UDT。 如果服务器不必序列化或反序列化 UDT,它不会在这些方面浪费时间;此外,它也不会浪费空间来存储 Null UDT。 每次从 CLR 中引入 UDT 时都会执行这种 Null 检查,也就是说,始终都应可以使用 Transact-SQL IS NULL 构造来检查有无 Null UDT。 IsNull属性还由服务器用来测试实例是否为 null。 一旦服务器确定 UDT 为 Null,它便可以使用其本机 Null 处理方法。
Get () 方法IsNull不以任何方式的特殊情况。 如果点变量**@p是Null**,然后**@p.IsNull** ,默认情况下,计算结果将为"NULL",不是"1"。 这是因为SqlMethod(OnNullCall) 的属性IsNull get () 方法默认值为 false。 因为对象是Null,该对象不反序列化,不调用该方法,并返回默认值为"NULL"请求属性时。
示例
在下面的示例中,is_Null 变量是私有的并且保存了 UDT 实例的 Null 状态。 您的代码必须保留 is_Null 的相应值。 UDT 还必须具有一个名为的静态属性Null返回 UDT 的 null 值实例。 这样,如果该实例在数据库中确实为 Null,UDT 便可返回 Null 值。
Private is_Null As Boolean
Public ReadOnly Property IsNull() As Boolean _
Implements INullable.IsNull
Get
Return (is_Null)
End Get
End Property
Public Shared ReadOnly Property Null() As Point
Get
Dim pt As New Point
pt.is_Null = True
Return (pt)
End Get
End Property
private bool is_Null;
public bool IsNull
{
get
{
return (is_Null);
}
}
public static Point Null
{
get
{
Point pt = new Point();
pt.is_Null = true;
return pt;
}
}
IS NULL 与IsNull
请考虑一个表,其中包含架构 Points (id int,定位点),该表点是 CLR UDT,并且有如下查询:
--Query 1
SELECT ID
FROM Points
WHERE NOT (location IS NULL) -- Or, WHERE location IS NOT NULL;
--Query 2:
SELECT ID
FROM Points
WHERE location.IsNull = 0;
这两个查询返回的点与非的 IdNull位置。 在 Query 1 中,使用的是正常 Null 处理方法,不需要反序列化 UDT。 查询 2,但是,必须反序列化每个非Null对象并调入 CLR 以获取的值IsNull属性。 很明显,使用IS NULL会表现出更好的性能,并且应该永远不会有理由继续阅读IsNull UDT 来自属性Transact-SQL代码。
那么,什么是使用IsNull属性? 首先,需要它来确定某个值是否Null从 CLR 代码中。 其次,服务器需要通过某种方式来测试实例是否为Null,因此服务器使用此属性。 它确定后Null,则它可以使用其本机 null 处理来对其进行处理。
实现 Parse 方法
分析并ToString方法允许用户定义的类型的字符串表示形式之间的转换。 分析方法允许将字符串转换为 UDT。 它必须声明为静态(或共享在 Visual Basic 中),并且采用的类型参数System.Data.SqlTypes.SqlString。
下面的代码实现分析方法点UDT,分隔开的 X 和 Y 坐标。 分析方法具有一个类型的参数System.Data.SqlTypes.SqlString,并假定,一个以逗号分隔的字符串形式提供 X 和 Y 值。 设置Microsoft.SqlServer.Server.SqlMethodAttribute.OnNullCall归于false阻止分析的 null 实例从被调用的方法点。
<SqlMethod(OnNullCall:=False)> _
Public Shared Function Parse(ByVal s As SqlString) As Point
If s.IsNull Then
Return Null
End If
' Parse input string here to separate out points.
Dim pt As New Point()
Dim xy() As String = s.Value.Split(",".ToCharArray())
pt.X = Int32.Parse(xy(0))
pt.Y = Int32.Parse(xy(1))
Return pt
End Function
[SqlMethod(OnNullCall = false)]
public static Point Parse(SqlString s)
{
if (s.IsNull)
return Null;
// Parse input string to separate out points.
Point pt = new Point();
string[] xy = s.Value.Split(",".ToCharArray());
pt.X = Int32.Parse(xy[0]);
pt.Y = Int32.Parse(xy[1]);
return pt;
}
实现 ToString 方法
ToString方法将点UDT 到一个字符串值。 在这种情况下,字符串"NULL"返回的 Null 实例点类型。 ToString方法相反分析方法通过使用System.Text.StringBuilder返回以逗号分隔System.String包含的 X 和 Y 坐标值。 因为InvokeIfReceiverIsNull默认值为 false,对的 null 实例的检查点是不必要的。
Private _x As Int32
Private _y As Int32
Public Overrides Function ToString() As String
If Me.IsNull Then
Return "NULL"
Else
Dim builder As StringBuilder = New StringBuilder
builder.Append(_x)
builder.Append(",")
builder.Append(_y)
Return builder.ToString
End If
End Function
private Int32 _x;
private Int32 _y;
public override string ToString()
{
if (this.IsNull)
return "NULL";
else
{
StringBuilder builder = new StringBuilder();
builder.Append(_x);
builder.Append(",");
builder.Append(_y);
return builder.ToString();
}
}
公开 UDT 属性
点UDT 公开作为类型的公共读写属性实现的 X 和 Y 坐标System.Int32。
Public Property X() As Int32
Get
Return (Me._x)
End Get
Set(ByVal Value As Int32)
_x = Value
End Set
End Property
Public Property Y() As Int32
Get
Return (Me._y)
End Get
Set(ByVal Value As Int32)
_y = Value
End Set
End Property
public Int32 X
{
get
{
return this._x;
}
set
{
_x = value;
}
}
public Int32 Y
{
get
{
return this._y;
}
set
{
_y = value;
}
}
验证 UDT 值
处理 UDT 数据时,SQL Server 数据库引擎会自动将二进制值转换为 UDT 值。 该转换过程包括检查值是否符合类型的序列化格式和确保可以正确地反序列化值。 这可确保,值可以转换回二进制形式。 对于采用字节顺序的 UDT,这样还可以确保产生的二进制值与原始二进制值匹配。 这会防止在数据库中保留无效值。 在某些情况下,只进行这种级别的检查可能是不够的。 当要求 UDT 值在预期的域或范围之内时可能需要进行其他验证。 例如,实现日期的 UDT 可能要求日值为特定的有效值范围内的正数。
Microsoft.SqlServer.Server.SqlUserDefinedTypeAttribute.ValidationMethodName的属性Microsoft.SqlServer.Server.SqlUserDefinedTypeAttribute可用于提供名称服务器在运行时的验证方法的数据是分配给 UDT 或转换为 UDT。 ValidationMethodName运行 bcp 实用工具、 BULK INSERT、 DBCC CHECKDB、 DBCC CHECKFILEGROUP、 DBCC CHECKTABLE、 分布式的查询和表格格式数据流 (TDS) 远程过程调用 (RPC) 操作期间也名为。 默认值为ValidationMethodName为空,表示没有验证方法。
示例
下面的代码段演示了用于声明点类,该类指定ValidationMethodName的ValidatePoint。
<Serializable(), SqlUserDefinedTypeAttribute(Format.Native, _
IsByteOrdered:=True, _
ValidationMethodName:="ValidatePoint")> _
Public Structure Point
[Serializable]
[Microsoft.SqlServer.Server.SqlUserDefinedType(Format.Native,
IsByteOrdered=true,
ValidationMethodName = "ValidatePoint")]
public struct Point : INullable
{
如果指定了验证方法,则必须具有如下面的代码段所示的签名。
Private Function ValidationFunction() As Boolean
If (validation logic here) Then
Return True
Else
Return False
End If
End Function
private bool ValidationFunction()
{
if (validation logic here)
{
return true;
}
else
{
return false;
}
}
验证方法可以具有任意作用域,应返回 ,则返回 true如果值有效,并且false否则为。 如果该方法返回false或引发异常,值被视为引发无效或错误。
在下面的示例中,代码仅允许零值或大于 X 和 Y 坐标的值。
Private Function ValidatePoint() As Boolean
If (_x >= 0) And (_y >= 0) Then
Return True
Else
Return False
End If
End Function
private bool ValidatePoint()
{
if ((_x >= 0) && (_y >= 0))
{
return true;
}
else
{
return false;
}
}
验证方法限制
服务器是在执行转换时调用验证方法,而不是在通过设置个别属性插入数据时或在使用 Transact-SQL INSERT 语句插入数据时调用验证方法。
必须显式从属性 setter 调用验证方法和分析方法如果你想要在所有情况下执行的验证方法。 并不要求这样做,在某些情况下可能甚至不需要这样做。
Parse 验证示例
若要确保ValidatePoint方法中调用点类,则必须调用它从分析方法和从设置 X 和 Y 属性过程坐标值。 下面的代码段演示如何调用ValidatePoint验证方法,从分析函数。
<SqlMethod(OnNullCall:=False)> _
Public Shared Function Parse(ByVal s As SqlString) As Point
If s.IsNull Then
Return Null
End If
' Parse input string here to separate out points.
Dim pt As New Point()
Dim xy() As String = s.Value.Split(",".ToCharArray())
pt.X = Int32.Parse(xy(0))
pt.Y = Int32.Parse(xy(1))
' Call ValidatePoint to enforce validation
' for string conversions.
If Not pt.ValidatePoint() Then
Throw New ArgumentException("Invalid XY coordinate values.")
End If
Return pt
End Function
[SqlMethod(OnNullCall = false)]
public static Point Parse(SqlString s)
{
if (s.IsNull)
return Null;
// Parse input string to separate out points.
Point pt = new Point();
string[] xy = s.Value.Split(",".ToCharArray());
pt.X = Int32.Parse(xy[0]);
pt.Y = Int32.Parse(xy[1]);
// Call ValidatePoint to enforce validation
// for string conversions.
if (!pt.ValidatePoint())
throw new ArgumentException("Invalid XY coordinate values.");
return pt;
}
属性验证示例
下面的代码段演示如何调用ValidatePoint从设置 X 和 Y 坐标的属性过程的验证方法。
Public Property X() As Int32
Get
Return (Me._x)
End Get
Set(ByVal Value As Int32)
Dim temp As Int32 = _x
_x = Value
If Not ValidatePoint() Then
_x = temp
Throw New ArgumentException("Invalid X coordinate value.")
End If
End Set
End Property
Public Property Y() As Int32
Get
Return (Me._y)
End Get
Set(ByVal Value As Int32)
Dim temp As Int32 = _y
_y = Value
If Not ValidatePoint() Then
_y = temp
Throw New ArgumentException("Invalid Y coordinate value.")
End If
End Set
End Property
public Int32 X
{
get
{
return this._x;
}
// Call ValidatePoint to ensure valid range of Point values.
set
{
Int32 temp = _x;
_x = value;
if (!ValidatePoint())
{
_x = temp;
throw new ArgumentException("Invalid X coordinate value.");
}
}
}
public Int32 Y
{
get
{
return this._y;
}
set
{
Int32 temp = _y;
_y = value;
if (!ValidatePoint())
{
_y = temp;
throw new ArgumentException("Invalid Y coordinate value.");
}
}
}
UDT 方法编码
编写 UDT 方法时,请考虑所用的算法是否可能会随时间的推移而改变。 如果可能改变的话,最好考虑为您的 UDT 所用的方法创建一个单独的类。 如果算法发生变化,则可以使用新代码重新编译该类并将程序集加载到 SQL Server 中,而不会影响 UDT。 在许多情况下,都可以使用 Transact-SQL ALTER ASSEMBLY 语句重新加载 UDT,但这可能会使现有数据出现问题。 例如,货币UDT 附带AdventureWorks示例数据库使用ConvertCurrency函数转换货币值,这实现在单独的类。 在未来,转换算法可能会发生不可预知的变化,或者可能需要新的功能。 分隔ConvertCurrency函数从货币UDT 实现规划的未来更改时提供更大的灵活性。
示例
点类包含三个简单的方法来计算距离:距离, DistanceFrom并DistanceFromXY。 每个返回双计算的距离点为零,到指定点的距离点,并且从指定 X 和 Y 坐标向点。 距离并DistanceFrom每次调用DistanceFromXY,并演示如何使用不同的每个方法的参数。
' Distance from 0 to Point.
<SqlMethod(OnNullCall:=False)> _
Public Function Distance() As Double
Return DistanceFromXY(0, 0)
End Function
' Distance from Point to the specified point.
<SqlMethod(OnNullCall:=False)> _
Public Function DistanceFrom(ByVal pFrom As Point) As Double
Return DistanceFromXY(pFrom.X, pFrom.Y)
End Function
' Distance from Point to the specified x and y values.
<SqlMethod(OnNullCall:=False)> _
Public Function DistanceFromXY(ByVal ix As Int32, ByVal iy As Int32) _
As Double
Return Math.Sqrt(Math.Pow(ix - _x, 2.0) + Math.Pow(iy - _y, 2.0))
End Function
// Distance from 0 to Point.
[SqlMethod(OnNullCall = false)]
public Double Distance()
{
return DistanceFromXY(0, 0);
}
// Distance from Point to the specified point.
[SqlMethod(OnNullCall = false)]
public Double DistanceFrom(Point pFrom)
{
return DistanceFromXY(pFrom.X, pFrom.Y);
}
// Distance from Point to the specified x and y values.
[SqlMethod(OnNullCall = false)]
public Double DistanceFromXY(Int32 iX, Int32 iY)
{
return Math.Sqrt(Math.Pow(iX - _x, 2.0) + Math.Pow(iY - _y, 2.0));
}
使用 SqlMethod 属性
Microsoft.SqlServer.Server.SqlMethodAttribute类提供可用于标记方法定义以便指定 null 调用行为的确定性,以及指定的方法是否是赋值函数的自定义属性。 使用的是这些属性的默认值,仅在需要非默认值时才使用自定义特性。
Note:
SqlMethodAttribute类继承自SqlFunctionAttribute类,因此SqlMethodAttribute继承FillRowMethodName并TableDefinition字段从SqlFunctionAttribute。 这意味着可以编写一个不属于此情况的表值方法。 方法能够编译并且程序集部署,但出现错误有关IEnumerable返回类型是在运行时出现以下消息:"方法、 属性或字段 '<名称 >' 中类<类> 中的程序集<程序集 > 具有无效的返回类型。"
下表介绍的部分相关Microsoft.SqlServer.Server.SqlMethodAttribute属性可在 UDT 方法,并列出其默认值。
DataAccess
指示函数是否需要访问存储在 SQL Server 的本地实例中的用户数据。 默认值是DataAccessKind。无。
IsDeterministic
指示在输入值相同且数据库状态相同的情况下函数是否会生成相同的输出值。 默认值是false。
IsMutator
指示方法是否在 UDT 实例中引起状态变化。 默认值是false。
IsPrecise
指示函数是否涉及不精确的计算,如浮点运算。 默认值是false。
OnNullCall
指示在指定 Null 引用输入参数时是否调用此方法。 默认值是 ,则返回 true。
示例
Microsoft.SqlServer.Server.SqlMethodAttribute.IsMutator属性可以标记允许 UDT 实例状态的更改的方法。 Transact-SQL 不允许在一个 UPDATE 语句的 SET 子句中设置两个 UDT 属性。 然而,您可以将一个方法标记为更改两个成员的赋值函数。
Note:
在查询中不允许使用赋值函数方法。 这些方法只能在赋值语句或数据修改语句中调用。 如果一个方法标记为赋值函数不会返回void (或不是Sub在 Visual Basic 中),CREATE TYPE 失败并出现错误。
下面的语句假定存在三角形UDT 具有旋转方法。 以下Transact-SQL更新语句调用旋转方法:
UPDATE Triangles SET t.RotateY(0.6) WHERE id=5
旋转方法用修饰SqlMethod属性设置IsMutator到true以便SQL Server可以将标记形式的赋值函数方法的方法。 此代码还设置OnNullCall到false,其中向服务器指示该方法返回空引用 (Nothing在 Visual Basic 中) 如果任何输入参数为 null 引用。
<SqlMethod(IsMutator:=True, OnNullCall:=False)> _
Public Sub Rotate(ByVal anglex as Double, _
ByVal angley as Double, ByVal anglez As Double)
RotateX(anglex)
RotateY(angley)
RotateZ(anglez)
End Sub
[SqlMethod(IsMutator = true, OnNullCall = false)]
public void Rotate(double anglex, double angley, double anglez)
{
RotateX(anglex);
RotateY(angley);
RotateZ(anglez);
}
采用用户定义的格式实现 UDT
在实现时采用用户定义的格式的 UDT,必须实现读并编写实现了 Microsoft.SqlServer.Server.IBinarySerialize 接口以处理序列化的方法和反序列化 UDT 数据。 此外必须指定MaxByteSize的属性Microsoft.SqlServer.Server.SqlUserDefinedTypeAttribute。
Currency UDT
货币UDT 是可以使用安装的 CLR 示例附带SQL Server开始, SQL Server 2005。
货币UDT 支持中的特定区域性的货币体系处理大量的资金。 必须定义两个字段:字符串有关CultureInfo,它指定货币的颁发者 (en-我们示例中) 和一个十进制为CurrencyValue,货币量。
尽管不使用由服务器来执行比较,但货币UDT 实现System.IComparable接口,公开了一个方法, System.IComparable.CompareTo。 在需要精确比较或排序区域性中的货币值的情况下,在客户端会使用此方法。
在 CLR 中运行的代码将区域性与货币值分开比较。 对于 Transact-SQL 代码,通过执行下列操作来确定如何比较:
-
设置IsByteOrdered属性为 true,它会告知SQL Server使用磁盘上保留的二进制表示形式进行比较。
-
使用编写方法货币UDT 便可确定如何保持 UDT 在磁盘上,因此如何比较和排序的 UDT 值Transact-SQL操作。
-
保存货币使用以下二进制格式的 UDT:
-
将区域性另存为 UTF-16 编码的字符串并用第 0-19 个字节表示,右侧以 Null 字符填充。
-
使用第 20 个字节及以后的字节包含货币的十进制值。
-
填充的目的是为了确保区域性与货币值完全分开,以便在 Transact-SQL 代码中将一个 UDT 与另一个 UDT 进行比较时,区域性字节与区域性字节相比较,货币字节值与货币字节值相比较。
有关完整代码清单货币UDT,按照中示例的说明安装 CLR SQL Server 数据库引擎示例。
Currency 属性
货币UDT 定义具有以下属性。
<Serializable(), Microsoft.SqlServer.Server.SqlUserDefinedType( _
Microsoft.SqlServer.Server.Format.UserDefined, _
IsByteOrdered:=True, MaxByteSize:=32), _
CLSCompliant(False)> _
Public Structure Currency
Implements INullable, IComparable, _
Microsoft.SqlServer.Server.IBinarySerialize
[Serializable]
[SqlUserDefinedType(Format.UserDefined,
IsByteOrdered = true, MaxByteSize = 32)]
[CLSCompliant(false)]
public struct Currency : INullable, IComparable, IBinarySerialize
{
创建带有 IBinarySerialize 的 Read 和 Write 方法
当你选择UserDefined序列化格式,还必须实现IBinarySerialize接口,并创建您自己读取和编写方法。 以下过程从货币UDT 使用System.IO.BinaryReader并System.IO.BinaryWriter读取和写入 UDT。
' IBinarySerialize methods
' The binary layout is as follow:
' Bytes 0 - 19: Culture name, padded to the right with null
' characters, UTF-16 encoded
' Bytes 20+: Decimal value of money
' If the culture name is empty, the currency is null.
Public Sub Write(ByVal w As System.IO.BinaryWriter) _
Implements Microsoft.SqlServer.Server.IBinarySerialize.Write
If Me.IsNull Then
w.Write(nullMarker)
w.Write(System.Convert.ToDecimal(0))
Return
End If
If cultureName.Length > cultureNameMaxSize Then
Throw New ApplicationException(String.Format(CultureInfo.CurrentUICulture, _
"{0} is an invalid culture name for currency as it is too long.", cultureNameMaxSize))
End If
Dim paddedName As String = cultureName.PadRight(cultureNameMaxSize, CChar(vbNullChar))
For i As Integer = 0 To cultureNameMaxSize - 1
w.Write(paddedName(i))
Next i
' Normalize decimal value to two places
currencyVal = Decimal.Floor(currencyVal * 100) / 100
w.Write(currencyVal)
End Sub
Public Sub Read(ByVal r As System.IO.BinaryReader) _
Implements Microsoft.SqlServer.Server.IBinarySerialize.Read
Dim name As Char() = r.ReadChars(cultureNameMaxSize)
Dim stringEnd As Integer = Array.IndexOf(name, CChar(vbNullChar))
If stringEnd = 0 Then
cultureName = Nothing
Return
End If
cultureName = New String(name, 0, stringEnd)
currencyVal = r.ReadDecimal()
End Sub
// IBinarySerialize methods
// The binary layout is as follow:
// Bytes 0 - 19:Culture name, padded to the right
// with null characters, UTF-16 encoded
// Bytes 20+:Decimal value of money
// If the culture name is empty, the currency is null.
public void Write(System.IO.BinaryWriter w)
{
if (this.IsNull)
{
w.Write(nullMarker);
w.Write((decimal)0);
return;
}
if (cultureName.Length > cultureNameMaxSize)
{
throw new ApplicationException(string.Format(
CultureInfo.InvariantCulture,
"{0} is an invalid culture name for currency as it is too long.",
cultureNameMaxSize));
}
String paddedName = cultureName.PadRight(cultureNameMaxSize, '\0');
for (int i = 0; i < cultureNameMaxSize; i++)
{
w.Write(paddedName[i]);
}
// Normalize decimal value to two places
currencyValue = Decimal.Floor(currencyValue * 100) / 100;
w.Write(currencyValue);
}
public void Read(System.IO.BinaryReader r)
{
char[] name = r.ReadChars(cultureNameMaxSize);
int stringEnd = Array.IndexOf(name, '\0');
if (stringEnd == 0)
{
cultureName = null;
return;
}
cultureName = new String(name, 0, stringEnd);
currencyValue = r.ReadDecimal();
}
有关完整代码清单货币UDT,请参阅SQL Server 数据库引擎示例。
请参阅
历史资料。此文对应 2018-11-30 的中文文档快照,适用产品版本和命令行为以原文为准。
来源与署名:Microsoft 和文档贡献者(原始作者元数据 rothja)。固定版本原文。文档采用 CC BY 4.0,示例代码采用 MIT 授权。本站展开固定版本仓库内的引用内容,将 Markdown 转为 HTML,规范化链接,移除外部媒体、发布器占位标签和导航标记。
